# Temporarily extend module path for bundled find package scripts
set(_vanetza_save_cmake_module_path ${CMAKE_MODULE_PATH})
list(APPEND CMAKE_MODULE_PATH "@PROJECT_SOURCE_DIR@/cmake")

include(CMakeFindDependencyMacro)
find_dependency(Boost @Boost_VERSION_STRING@ CONFIG COMPONENTS date_time)

if(@VANETZA_WITH_GEOGRAPHICLIB@)
    find_dependency(GeographicLib @GeographicLib_VERSION_STRING@)
endif()

if(@VANETZA_WITH_RPC@)
    find_dependency(CapnProto @CapnProto_VERSION@)
endif()

if(@VANETZA_WITH_CRYPTOPP@)
    find_dependency(CryptoPP @CryptoPP_VERSION_STRING@)
endif()

if(@VANETZA_WITH_OPENSSL@)
    # remove patch letter found with OpenSSL 1.x
    string(REGEX REPLACE "[a-z]+$" "" OpenSSL_VERSION_WITHOUT_PATCH "@OpenSSL_VERSION@")
    find_dependency(OpenSSL ${OpenSSL_VERSION_WITHOUT_PATCH})
endif()

if(@VANETZA_WITH_PQC@)
    find_dependency(liboqs 0.14 CONFIG)
endif()

# Restore previous module path
set(CMAKE_MODULE_PATH ${_vanetza_save_cmake_module_path})
unset(_vanetza_save_cmake_module_path)

include("${CMAKE_CURRENT_LIST_DIR}/VanetzaExports.cmake")