Ashin Walpola
0e9525162d
obu-firmware builds against vanetza-idf from microbu-esp32c5/external, but that tree was gitignored, so a clone of this repository could not build the firmware it ships. It is now committed here as ordinary files in its own folder, microbu-esp32c5/: the colleague's commit cf4b99f plus the V2X2MAP bridge's signature verification (--trust) used on the bench. Nothing is fetched from or pushed to the colleague's repository; this repository and its remotes carry everything. The folder's own .gitignore keeps build output, downloaded components and private key material out, as it did there; the committed file set is identical to that repository's tracked files. The ESP32-C5 is still flashed from obu-firmware/, which only takes vanetza-idf from microbu-esp32c5/, so the two stay separate folders. FLASHING.md says how to take a newer version of the colleague's tree (copy it over the folder, rebuild, test, commit).
28 lines
1.1 KiB
CMake
28 lines
1.1 KiB
CMake
find_path(GPS_INCLUDE_DIR NAMES gps.h DOC "libgps include directory")
|
|
find_library(GPS_LIBRARY NAMES gps DOC "libgps library")
|
|
|
|
if(GPS_INCLUDE_DIR)
|
|
file(STRINGS ${GPS_INCLUDE_DIR}/gps.h _version_lines REGEX "GPSD_API_(MAJOR|MINOR)_VERSION")
|
|
string(REGEX MATCH "MAJOR_VERSION[ \t]+([0-9]+)" _version_major ${_version_lines})
|
|
set(GPS_VERSION_MAJOR ${CMAKE_MATCH_1})
|
|
string(REGEX MATCH "MINOR_VERSION[ \t]+([0-9]+)" _version_minor ${_version_lines})
|
|
set(GPS_VERSION_MINOR ${CMAKE_MATCH_1})
|
|
set(GPS_VERSION_STRING "${GPS_VERSION_MAJOR}.${GPS_VERSION_MINOR}")
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(GPS
|
|
REQUIRED_VARS GPS_INCLUDE_DIR GPS_LIBRARY
|
|
VERSION_VAR GPS_VERSION_STRING)
|
|
|
|
if(GPS_FOUND AND NOT TARGET GPS::GPS)
|
|
add_library(GPS::GPS UNKNOWN IMPORTED)
|
|
set_target_properties(GPS::GPS PROPERTIES
|
|
IMPORTED_LOCATION "${GPS_LIBRARY}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${GPS_INCLUDE_DIR}")
|
|
endif()
|
|
|
|
mark_as_advanced(GPS_INCLUDE_DIR GPS_LIBRARY)
|
|
set(GPS_INCLUDE_DIRS ${GPS_INCLUDE_DIR})
|
|
set(GPS_LIBRARIES ${GPS_LIBRARY})
|